2511 Rate this article:
No rating

Positioning plots

Mark Alonzo
Last week, I gave an example of creating a multi-panel plot (or multiplot) using the LAYOUT keyword. Today (with a nod to a comment from Paul Young), I'll show an alternate technique using the POSITION keyword. The Solar Physics Group at NASA's Marshall Space Flight Center provides information on the sunspot cycle. You can download the group's monthly sunspot number data—dating back to 1749!—here (TXT). I'd like to display, side-by-side, a plot of the sunspot series since 1970 and a histogram of the series. Start by reading the data from the file, assuming it's included in your IDL path. I prefer the astrolib READCOL procedure for reading text files.
file = file_which('spot_num.txt')
readcol, file, year, month, sunspots
Next, create a time vector and use it to restrict our analysis to sunspot activity since 1970:
time = year + (month-1.0)/12.0
i_ge1970 = where(time ge 1970.0, /null)
time_recent = time[i_ge1970]
sunspots_recent = sunspots[i_ge1970]
Now use HISTOGRAM to calculate a discrete frequency distribution of the sunspot numbers since 1970:
sunspot_histogram = histogram(sunspots_recent, $
   binsize=10, $
   locations=sunspot_bins)
I've empirically chosen a bin size of 10, and returned the locations of the bins into the variable sunspot_bins. The first plot, positioned on the left, is of the sunspot series:
xr = minmax(time_recent)
yr = minmax(sunspots_recent)
series = plot(time_recent, sunspots_recent, $
   dimensions=[800,600], $
   position=[0.10, 0.15, 0.75, 0.90], $
   xrange=xr, yrange=yr, $
   xtitle='Year', ytitle='Sunspots', $
   title='Sunspot Activity (1970-present)')
The key in this call to PLOT is the POSITION keyword: this four-element array describes the lower left [0.10, 0.15] and upper right [0.75,0.90] corners of the bounding box of the plot, in normalized coordinates. The plot fits within this box. I've also used the convenient astrolib MINMAX function to set up axis ranges for the plot, and the DIMENSIONS property to set the size of the plot window, in pixels. The second plot, positioned to the right of the first, displays the histogram of the sunspot series:
histoplot = plot(sunspot_histogram, sunspot_bins, $
   position=[0.80, 0.15, 0.95, 0.90], /current, $
   /histogram, $              ; IDL 8.2.1
   yrange=series.yrange, $    ; match yrange of first plot
   ymajor=0, $                ; no axis text
   /fill_background, fill_color='light gray', $
   xtitle='Frequency', title='Histogram')
Swapping the order of the parameters to PLOT transposes the histogram. POSITION is used again to position the plot. CURRENT ensures this plot appears in the same window as series. The HISTOGRAM property tells IDL to draw discrete blocks instead of point-to-point lines (hi, Haje!). Here's my result: Sunspot series and histogram I like this pair of plots because scanning horizontally across the time series gives a visual estimate of the histogram displayed on the right. Next week, I'll perform some simple time series analyses on these data.

Please login or register to post comments.