2402 Rate this article:
No rating

Discrete colorbar in (New) Graphics

Mark Alonzo
The improved NG COLORBAR function in IDL 8.2 makes it much easier to display a discrete colorbar. The  example below is adapted from one of the IDLffVideoWrite examples I created for IDL 8.1; here, I use NCEP/NCAR Reanalysis 1 data to display the mean global 500 mb geopotential height surface for a single day as a filled contour plot with a discrete colorbar. I’ve chosen to write this example as a procedure. Start by locating the data file (it’s netCDF and I’m assuming it’s in IDL’s path), then reading it with a helper routine:
pro view_nnrp500mbgph, save=save
   compile_opt idl2

   f = file_which('X174.29.255.181.65.14.23.9.nc', /include)
   x = read_nnrp500mbgph(f)
The return from READ_NNRP500MBGPH, x, is a hash containing keys ‘hgt’, ‘lon’, ‘lat’ and ‘time’. An aside: in READ_NNRP500MBGPH I had fun using IDL 8 language features in conjunction with our netCDF API. This may be worth a separate post. Next, set up a map projection:
   m = map('Orthographic', $
      center_latitude=30, $
      center_longitude=120, $
      limit=[-90, 0, 90, 360], $ ; crosses IDL
      /current, $
      title='Daily Mean 500mb Geopotential Heights', $
      color='gray')
I chose an orthographic projection that crosses the international date line. Now visualize the 500 mb geopotential height surface for 2010 January 1 as a filled contour plot, using a set of custom levels based on the data range:
   nlevels = 14
   levels = findgen(nlevels)*100 + 4700 ; m
   g_heights = contour(x['hgt',*,*,0], x['lon'], x['lat'], $
      overplot=m, $
      c_value=levels, $
      rgb_table=39, $
      grid_units='degrees', $
      /fill, $
      transparency=20)
In the hash x, ‘hgt’ is a 3D array of heights dimensioned by [longitude, latitude, day of the year]. In this case, the subscripts applied to ‘hgt’ give all of the longitudes and latitudes on the first day of the year. To finish, annotate the visualization with continental outlines, a colorbar and some reference text:
   g_continents = mapcontinents(color='black')
   g_colorbar = colorbar(target=g_heights, $
      orientation=1, $
      textpos=1, $
      font_size=10, $
      transparency=g_heights.transparency, $
      border=1, $ ; boxes around cells
      position=[0.86, 0.20, 0.88, 0.80], $
      title='Height (m)')
   g_date = text(0.05, 0.20, '2010 January 01', font_size=12)
   subtitle = ['NCEP/NCAR Reanalysis Project', $
      'http://www.esrl.noaa.gov/psd/data/gridded/data.ncep.reanalysis.html']
   g_subtitle = text(0.05, 0.05, subtitle, font_size=8)

   if keyword_set(save) then $
      m.save, 'view_nnrp500mbgph.png', resolution=300
end
Note that the call to COLORBAR isn’t significantly different than in IDL 8.1. Through its TARGET keyword, it sees the levels and colors used in the contour plot and displays them appropriately as a discrete set of 14 colors (not, as in 8.1, all 256 colors from color table 39).  End caps are displayed by default for a filled contour plot. The result: A contour plot of 500 mb geopotential heights Download the code and data for this example here. Please also check out the IDL Help page for COLORBAR; it has several examples that demonstrate its new behavior.

Please login or register to post comments.