3474 Rate this article:
3.0

Making movies with IDL, part I

Mark Alonzo
Over the years there have been many ways to make movies with IDL, but none of them have been great. I think we now have a robust solution: the IDLffVideoWrite class, introduced in IDL 8.1, wraps FFmpeg, which can create a movie in just about any format. This week, I’ll show an example of using IDLffVideoWrite with Direct Graphics (DG). Next week, I’ll show how to make a similar movie with (New) Graphics (NG). This example is written as a procedure. Start the program by declaring some test data and setting up the IDLffVideoWrite object:
pro dg_movie_ex
   compile_opt idl2

   data = dist(30)

   video_file = 'dg_movie_ex.mp4'
   video = idlffvideowrite(video_file)
   framerate = 10
   framedims = [640,512]
   stream = video.addvideostream(framedims[0], framedims[1], framerate)
The variable video is an object, an instance of IDLffVideoWrite. I chose to make an MPEG-4 video file; see the IDL Help for other supported formats. We configure the dimensions and frame rate of the single video stream that this file holds (files can hold multiple video and audio streams) with the AddVideoStream method. Next, switch to the DG Z buffer device and configure it:
   loadct, 1
   set_plot, 'z', /copy
   device, set_resolution=framedims, set_pixel_depth=24, decomposed=0
We’ll need the Z buffer for hidden line removal in the visualization, but it’s also convenient because it allows us to render the frames of the movie offscreen. The next step is where we make and load frames into the movie file:
   nframes = 50
   for i=0, nframes-1 do begin
      shade_surf, data, charsize=2.0, az=(15 + i), /save
      contour, data, nlevels=10, /t3d, zval=i/float(nframes), /overplot
      xyouts, 0.5, 0.9, 'IDL Movie Example - DG', align=0.5, charsize=2, /normal
      timestamp = video.put(stream, tvrd(true=1))
   endfor
There’s quite a bit going on in this code block. On each iteration of the loop:
  1. SHADE_SURF displays data as a shaded surface and rotates the surface one degree about its z axis.
  2. CONTOUR visualizes data as a planar contour plot in the 3D coordinate system set up by SHADE_SURF. The contour plot is moved upward by a fraction of the total height of the surface.
  3. XYOUTS adds the title at the top of the visualization.
  4. TVRD takes a picture of the Z buffer. The picture is a pixel-interleaved RGB image, with dimensions 3 x 640 x 512.
  5. The Put method of IDLffVideoWrite loads this picture as a frame into the video stream.
End the program by closing the Z buffer, returning to the windowing device and destroying the video object:
   device, /close
   set_plot, strlowcase(!version.os_family) eq 'windows' ? 'win' : 'x'
   video.cleanup
   print, 'File "' + video_file + '" written to current directory.'
end
Click below to see the resulting video on the VIS YouTube channel. [youtube http://www.youtube.com/watch?v=e1zSoZWBx6E] Sweet! Update: Here's the second example.  

1 comments on article "Making movies with IDL, part I"

Patrick Essien

This is very usefull

Please login or register to post comments.