Welcome to the Harris Geospatial product documentation center. Here you will find reference guides, help documents, and product libraries.


  >  Docs Center  >  ENVI API  >  Processing  >  FilterTiePointsByGlobalTransform

FilterTiePointsByGlobalTransform

ENVIFilterTiePointsByGlobalTransformTask

This task uses the global transform to filter tie points. For orthorectified images, nadir, or near-nadir images, the transformation model between the first and second image fits an RST transform. When the scene is rather flat and the sensor is very far from the scene, the transformation model between the two images fits a first-order polynomial transform. Global transform is the most common filtering method.

The following diagram shows where this task belongs within an image-to-image registration workflow:

References

Jin, Xiaoying. ENVI automated image registration solutions. Harris Geospatial Systems whitepaper (2017). Available online at http://www.harrisgeospatial.com/Portals/0/pdfs/ENVI_Image_Registration_Whitepaper.pdf.

Jin, Xiaoying, and Robert Schafer. Method and system for automatic registration of images. Exelis, Inc., assignee; now owned by Harris Corporation. U.S. Patent No. 9,245,201 (issued January 26, 2016).

Example


This example uses sample images from the Image Registration tutorial. The files are available on the ENVI Resource DVD under the /image_reg directory or from the ENVI Tutorials web page. Click the "ENVI Tutorial Data" hyperlink. Copy the files to your local drive.

; Start the application
e = ENVI()
 
; Open input rasters
File1 = 'quickbird_2.4m.dat'
File2 = 'ikonos_4.0m.dat'
Raster1 = e.OpenRaster(File1)
Raster2 = e.OpenRaster(File2)
 
; Get the auto tie point generation task from the catalog of ENVITasks
Task = ENVITask('GenerateTiePointsByCrossCorrelation')
 
; Define inputs
Task.INPUT_RASTER1 = Raster1
Task.INPUT_RASTER2 = Raster2
 
; Run the task
Task.Execute
 
; Get the output tie points
TiePoints = Task.OUTPUT_TIEPOINTS
 
; Get the tie point filter task from the catalog of ENVITasks
FilterTask = ENVITask('FilterTiePointsByGlobalTransform')
 
; Define inputs
FilterTask.INPUT_TIEPOINTS = TiePoints
 
; Run the task
FilterTask.Execute
 
; Get the output tie points
TiePoints2 = FilterTask.OUTPUT_TIEPOINTS
 
; Get the image-to-image registration task from the catalog of ENVITasks
RegistrationTask = ENVITask('ImageToImageRegistration')
 
; Define inputs
RegistrationTask.INPUT_TIEPOINTS = TiePoints2
RegistrationTask.WARPING = 'Triangulation'
 
; Run the task
RegistrationTask.Execute
 
; Get the output raster
WarpedRaster = RegistrationTask.OUTPUT_RASTER
 
; Get the collection of data objects currently available in the Data Manager
DataColl = e.Data
 
; Add the output to the Data Manager
DataColl.Add, WarpedRaster
 
; Display the input rasters
View1 = e.GetView()
Layer1 = View1.CreateLayer(Raster1)
Layer2 = View1.CreateLayer(Raster2)
 
; Display the result
Layer3 = View1.CreateLayer(WarpedRaster)

Syntax


Result = ENVITask('FilterTiePointsByGlobalTransform')

Input properties (Set, Get): ERROR_THRESHOLD, FITTING_TRANSFORM, INPUT_TIEPOINTS, OUTPUT_TIEPOINTS_URI

Output properties (Get only): OUTPUT_TIEPOINTS

Properties marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Properties marked as "Get" are those whose values you can retrieve but not set.

Methods


This task inherits the following methods from ENVITask:

AddParameter

Execute

Parameter

ParameterNames

RemoveParameter

Properties


This task inherits the following properties from ENVITask:

COMMUTE_ON_DOWNSAMPLE

COMMUTE_ON_SUBSET

DESCRIPTION

DISPLAY_NAME

NAME

REVISION

TAGS

This task also contains the following properties:

ERROR_THRESHOLD (optional)

Specify the maximum error to allow for each tie point. The tie point with the largest error distance from the predicted location is iteratively removed until no tie points have an error greater than the this value. Multiview images of a 3D scene contain local geometric differences due to variation in local terrain relief and difference in imaging view angle. If image misalignment is mainly due to local geometric differences, increase this value.

The default value is 5.0. A higher value keeps more tie points with larger fitting errors. If you prefer to keep most tie points, enter a high value, such as 100.

FITTING_TRANSFORM (optional)

Specify the transform to use when automatically filtering tie points. The default is First-Order Polynomial.

  • First-Order Polynomial: A first-order polynomial warp includes an XY interaction term to account for image shear.
  • RST: Rotation, scaling, and translation; this is the simplest method. It does not allow for shearing in the image warp.

INPUT_TIEPOINTS (required)

This is a reference to the ENVITiePointSet object generated from ENVIGenerateTiePointsByCrossCorrelationTask or ENVIGenerateTiePointsByMutualInformationTask.

OUTPUT_TIEPOINTS

This is a reference to an ENVITiePointSet object with the output tie points.

OUTPUT_TIEPOINTS_URI (optional)

Specify a string with the fully qualified path and filename for OUTPUT_TIEPOINTS.

Version History


ENVI 5.2, Service Pack 1

Introduced

API Version


3.2

See Also


ENVITask, ENVITask::Parameter, ENVIFilterTiePointsByFundamentalMatrixTask, ENVIFilterTiePointsByPushbroomModelTask, ENVIGenerateTiePointsByCrossCorrelationTask, ENVIGenerateTiePointsByMutualInformationTask, ENVIImageToImageRegistrationTask, ENVITiePointSet



© 2018 Harris Geospatial Solutions, Inc. |  Legal
My Account    |    Store    |    Contact Us