Welcome to the Harris Geospatial product documentation center. Here you will find reference guides, help documents, and product libraries.


Harris Geospatial / Docs Center / ENVI API / Processing / GenerateTiePointsByCrossCorrelationWithOrthorectification

GenerateTiePointsByCrossCorrelationWithOrthorectification

ENVIGenerateTiePointsByCrossCorrelationWithOrthorectificationTask

This task performs automatic tie point generation using cross correlation as a similarity measure. At least one input raster must have an RPC spatial reference. This method works well for general purposes, especially registering images with similar modality (e.g., registering optical images with optical images).

A DEM raster is required to perform orthorectification on-the-fly to geometrically correct the data before image matching.The higher the resolution and accuracy of the DEM data, the more tie points that are generated, and the better the distribution of those points.

The following diagram shows where this task belongs within an image-to-image registration workflow:

References

Jin, Xiaoying. ENVI automated image registration solutions. Harris Geospatial Systems whitepaper (2017). Available online at http://www.harrisgeospatial.com/Portals/0/pdfs/ENVI_Image_Registration_Whitepaper.pdf.

Jin, Xiaoying, and Robert Schafer. Method and system for automatic registration of images. Exelis, Inc., assignee; now owned by Harris Corporation. U.S. Patent No. 9,245,201 (issued January 26, 2016).

Example


This example uses sample Quickbird images and a USGS SRTM 1-arc second DEM. The files are available on the ENVI Resource DVD under the /image_reg directory or from the ENVI Tutorials web page. Click the "ENVI Tutorial Data" hyperlink. Copy the files to your local drive.

; Start the application
e = ENVI()
 
; Open QuickBird images and SRTM 1-arc second DEM
file1 = 'QuickBirdPhoenixWest.dat'
raster1 = e.OpenRaster(file1)
 
file2 = 'QuickBirdPhoenixEast.dat'
raster2 = e.OpenRaster(file2)
 
DEMFile = 'PhoenixDEMSubset.dat'
DEMRaster = e.OpenRaster(DEMFile)
 
; Get the task from the catalog of ENVITasks
Task = ENVITask('GenerateTiePointsByCrossCorrelationWithOrthorectification')
 
; Define inputs
Task.INPUT_RASTER1 = raster1
Task.INPUT_RASTER2 = raster2
Task.INPUT_DEM_RASTER = DEMRaster
Task.REQUESTED_NUMBER_OF_TIEPOINTS = 40
 
; Define outputs
Task.OUTPUT_TIEPOINTS_URI = e.GetTemporaryFilename('pts')
Task.OUTPUT_ORTHORECTIFIED_TIEPOINTS_URI = e.GetTemporaryFilename('pts')
 
; Run the task
Task.Execute
 
; Get the output tie points
TiePoints = Task.OUTPUT_TIEPOINTS
OrthoTiePoints = Task.OUTPUT_ORTHORECTIFIED_TIEPOINTS
 
; Get the tie point filter task from the catalog of ENVITasks
FilterTask = ENVITask('FilterTiePointsByGlobalTransformWithOrthorectification')
 
; Define inputs for the filtering task
FilterTask.INPUT_TIEPOINTS = TiePoints
FilterTask.INPUT_ORTHORECTIFIED_TIEPOINTS = OrthoTiePoints
 
; Run the task
FilterTask.Execute
 
; Define outputs for the filtering task
FilteredTiePoints = FilterTask.OUTPUT_TIEPOINTS
 
; Get the image-to-image registration task
RegTask = ENVITask('ImageToImageRegistration')
 
; Define inputs
RegTask.INPUT_TIEPOINTS = FilteredTiePoints
RegTask.WARPING = 'Triangulation'
 
; Run the image-to-image registration task
RegTask.Execute
 
; Get the output raster
WarpedRaster = RegTask.OUTPUT_RASTER
 
; Get the collection of data objects currently available in the Data Manager
DataColl = e.Data
 
; Add the output to the Data Manager
DataColl.Add, WarpedRaster
 
; Display the result
View = e.GetView()
Layer = View.CreateLayer(WarpedRaster)

Syntax


Result = ENVITask('GenerateTiePointsByCrossCorrelationWithOrthorectification')

Input properties (Set, Get): IGNORE_VALIDATE, INPUT_DEM_RASTER, INPUT_RASTER1, INPUT_RASTER2, INPUT_SEED_TIEPOINTS, INTEREST_OPERATOR, MATCHING_WINDOW, MINIMUM_MATCHING_SCORE, NO_GEOID_CORRECTION, OUTPUT_ORTHORECTIFIED_TIEPOINTS_URI, OUTPUT_TIEPOINTS_URI, REQUESTED_NUMBER_OF_TIEPOINTS, SEARCH_WINDOW

Output properties (Get only): DESCRIPTION, MATCHING_SCORES, NAME, OUTPUT_ORTHORECTIFIED_TIEPOINTS, OUTPUT_TIEPOINTS

Properties marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Properties marked as "Get" are those whose values you can retrieve but not set.

Methods


This task inherits the following methods from ENVITask:

AddParameter

Execute

Parameter

ParameterNames

RemoveParameter

Properties


DESCRIPTION

This property describes the task.

IGNORE_VALIDATE (optional)

This property is now deprecated and has no effect on task behavior. All task property values are validated when they are set, and they throw an error with bad input.

INPUT_DEM_RASTER (required)

Specify a DEM raster. At least one input raster must have an RPC spatial reference. Image templates are orthorectified to geometrically correct the data before image matching.

INPUT_RASTER1 (required)

Specify the first raster.

INPUT_RASTER2 (required)

Specify the second raster.

INPUT_SEED_TIEPOINTS (optional)

This is a reference to an ENVITiePointSet object with input seed tie points.

INTEREST_OPERATOR (optional)

Specify the interest operator to use to identify feature points. The default value is Forstner.

  • Forstner: Obtains and analyzes the gray scale gradient matrix between one pixel and its adjacent pixels. The Forstner operator is typically better for image matching than the Moravec operator.
  • Moravec: Seearches for gray scale value differences between one pixel and its adjacent pixels. The Moravec operator is typically faster than the Forstner operator.
  • Harris: Improves upon Moravec by using the auto-correlation matrix and avoids using discrete directions and shifts.

MATCHING_SCORES (optional)

The normalized cross-correlation between the matching windows (specified with the MATCHING_WINDOW property) in both input images is computed as the matching score. This value is a double-precision array in the form [number of tie points].

This is an advanced property designed for users who want more control over filtering tie points by matching scores. See Example: Matching Scores in the ENVIGenerateTiePointsByCrossCorrelation topic for a code example.

MATCHING_WINDOW (optional)

Specify the matching window size used for computing the matching score between the two images. The default value is 61.

MINIMUM_MATCHING_SCORE (optional)

Specify the minimum matching score to automatically remove the tie points if the matching score is less than the value. The default value is 0.6. To register images with different modalities (e.g., registering SAR with optical images), set the minimum matching score to a lower value.

NAME

This property contains the name of the task.

NO_GEOID_CORRECTION (optional)

Set this to true if the DEM represents ellipsoid height and no geoid correction is needed. The default value is false.

OUTPUT_ORTHORECTIFIED_TIEPOINTS

This is a reference to the output orthorectified tie points.

OUTPUT_ORTHORECTIFIED_TIEPOINTS_URI (optional)

Specify a string with the fully-qualified path and filename for OUTPUT_ORTHORECTIFIED_TIEPOINTS.

OUTPUT_TIEPOINTS

This is a reference to an ENVITiePointSet object with the output tie points.

OUTPUT_TIEPOINTS_URI (optional)

Specify a string with the fully qualified path and filename for OUTPUT_TIEPOINTS.

REQUESTED_NUMBER_OF_TIEPOINTS (optional)

Specify the requested number of tie points. The default value is 121.

SEARCH_WINDOW (optional)

Specify the tolerance for the search range. The default value is 255.

Version History


ENVI 5.2, Service Pack 1

Introduced

API Version


3.1.0

See Also


ENVITask, ENVITask::Parameter, ENVISubsetRaster, ENVIGenerateTiePointsByMutualInformationWithOrthorectificationTask, ENVIFilterTiePointsByGlobalTransformWithOrthorectificationTask, ENVIFilterTiePointsByFundamentalMatrixTask, ENVIFilterTiePointsByPushbroomModelTask, ENVIImageToImageRegistrationTask, ENVITiePointSet



© 2017 Exelis Visual Information Solutions, Inc. |  Legal
My Account    |    Buy    |    Contact Us