Welcome to the Harris Geospatial product documentation center. Here you will find reference guides, help documents, and product libraries.


  >  Docs Center  >  ENVI API  >  Processing  >  GenerateTiePointsByMutualInformation

GenerateTiePointsByMutualInformation

ENVIGenerateTiePointsByMutualInformationTask

This task performs automatic tie point generation using mutual information as a similarity measure. This method is optimized for registering images with different modalities (e.g., registering SAR with optical images, or thermal with visible images).

The normalized mutual information between the patch in the first image and the patch in the second image is computed as the matching score. Mutual information is based on information theory and measures the mutual dependence of the two random variables. Mutual information produces more accurate results than the traditional correlation-based measures for cross-modality image registration. This method takes longer to run since it is more computationally intensive.

The following diagram shows where this task belongs within an image-to-image registration workflow:

References

Jin, Xiaoying. ENVI automated image registration solutions. Harris Geospatial Systems whitepaper (2017). Available online at http://www.harrisgeospatial.com/Portals/0/pdfs/ENVI_Image_Registration_Whitepaper.pdf.

Jin, Xiaoying, and Robert Schafer. Method and system for automatic registration of images. Exelis, Inc., assignee; now owned by Harris Corporation. U.S. Patent No. 9,245,201 (issued January 26, 2016).

Example


This example uses sample images from the Image Registration tutorial. The files are available on the ENVI Resource DVD under the /image_reg directory or from the ENVI Tutorials web page. Click the "ENVI Tutorial Data" hyperlink. Copy the files to your local drive.

; Start the application
e = ENVI()
 
; Open input rasters
File1 = 'quickbird_2.4m.dat'
File2 = 'ikonos_4.0m.dat'
Raster1 = e.OpenRaster(File1)
Raster2 = e.OpenRaster(File2)
 
; Get the auto tie point generation task from the catalog of ENVITasks
Task = ENVITask('GenerateTiePointsByMutualInformation')
 
; Define inputs
Task.INPUT_RASTER1 = Raster1
Task.INPUT_RASTER2 = Raster2
 
; Run the task
Task.Execute
 
; Get the output tie points
TiePoints = Task.OUTPUT_TIEPOINTS
 
; Get the tie point filter task from the catalog of ENVITasks
FilterTask = ENVITask('FilterTiePointsByGlobalTransform')
 
; Define inputs
FilterTask.INPUT_TIEPOINTS = TiePoints
 
; Run the task
FilterTask.Execute
 
; Get the output tie points
TiePoints2 = FilterTask.OUTPUT_TIEPOINTS
 
; Get the image-to-image registration task from the catalog of ENVITasks
RegistrationTask = ENVITask('ImageToImageRegistration')
 
; Define inputs
RegistrationTask.INPUT_TIEPOINTS = TiePoints2
RegistrationTask.WARPING = 'Triangulation'
 
; Run the task
RegistrationTask.Execute
 
; Get the output raster
WarpedRaster = RegistrationTask.OUTPUT_RASTER
 
; Get the collection of data objects currently available in the Data Manager
DataColl = e.Data
 
; Add the output to the Data Manager
DataColl.Add, WarpedRaster
 
; Display the input rasters
View1 = e.GetView()
Layer1 = View1.CreateLayer(Raster1)
Layer2 = View1.CreateLayer(Raster2)
 
; Display the result
Layer3 = View1.CreateLayer(WarpedRaster)

Syntax


Result = ENVITask('GenerateTiePointsByMutualInformation')

Input properties (Set, Get): INPUT_RASTER1, INPUT_RASTER2, INPUT_SEED_TIEPOINTS, INTEREST_OPERATOR, MATCHING_WINDOW, MINIMUM_MATCHING_SCORE, OUTPUT_TIEPOINTS_URI, REQUESTED_NUMBER_OF_TIEPOINTS, SEARCH_WINDOW

Output properties (Get only): MATCHING_SCORES, OUTPUT_TIEPOINTS

Properties marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Properties marked as "Get" are those whose values you can retrieve but not set.

Methods


This task inherits the following methods from ENVITask:

AddParameter

Execute

Parameter

ParameterNames

RemoveParameter

Properties


This task inherits the following properties from ENVITask:

COMMUTE_ON_DOWNSAMPLE

COMMUTE_ON_SUBSET

DESCRIPTION

DISPLAY_NAME

NAME

REVISION

TAGS

This task also contains the following properties:

INPUT_RASTER1 (required)

Specify the first raster.

INPUT_RASTER2 (required)

Specify the second raster.

INPUT_SEED_TIEPOINTS (optional)

This is a reference to an ENVITiePointSet object with input seed tie points.

INTEREST_OPERATOR (optional)

Specify the interest operator to use to identify feature points. The default value is Forstner.

  • Forstner: Obtains and analyzes the gray scale gradient matrix between one pixel and its adjacent pixels. The Forstner operator is typically better for image matching than the Moravec operator.
  • Moravec: Seearches for gray scale value differences between one pixel and its adjacent pixels. The Moravec operator is typically faster than the Forstner operator.
  • Harris: Improves upon Moravec by using the auto-correlation matrix and avoids using discrete directions and shifts.

MATCHING_WINDOW (optional)

Specify the matching window size used for computing the matching score between the two images. The default value is 61.

MATCHING_SCORES (optional)

The normalized mutual information between the matching windows (specified with the MATCHING_WINDOW property) in both input images is computed as the matching score. This value is a double-precision array in the form [number of tie points].

This is an advanced property designed for users who want more control over filtering tie points by matching scores. See Example: Matching Scores for a code example.

MINIMUM_MATCHING_SCORE (optional)

Specify the minimum matching score to automatically remove the tie points if the matching score is less than the value. The default value is 0.6.

OUTPUT_TIEPOINTS

This is a reference to an ENVITiePointSet object with the output tie points.

OUTPUT_TIEPOINTS_URI (optional)

Specify a string with the fully qualified path and filename for OUTPUT_TIEPOINTS.

REQUESTED_NUMBER_OF_TIEPOINTS (optional)

Specify the requested number of tie points. The default value is 121.

SEARCH_WINDOW (optional)

Specify the tolerance for the search range. The default value is 255.

Example: Matching Scores


The folloing script shows how to use the MATCHING_SCORES property to filter tie points using matching scores:

; Start the application
e = ENVI()
 
; Open input rasters
File1 = 'quickbird_2.4m.dat'
File2 = 'ikonos_4.0m.dat'
Raster1 = e.OpenRaster(File1)
Raster2 = e.OpenRaster(File2)
 
; Get the auto tie point generation task 
; from the catalog of ENVITasks
Task = ENVITask('GenerateTiePointsByMutualInformation')
 
; Define inputs
Task.INPUT_RASTER1 = Raster1
Task.INPUT_RASTER2 = Raster2
Task.MINIMUM_MATCHING_SCORE = 0.0
 
; Run the task
Task.Execute
 
; Filter the tie points by matching scores 
; and remove any outliers
TiePointSet = Task.OUTPUT_TIEPOINTS
MatchingScore = Task.MATCHING_SCORES
 
Indices = Where(MatchingScore ge 0.6)
Tiepoints = TiePointSet.Get(Indices)
FilteredTiePoints = ENVITiePointSet(TIEPOINTS=Tiepoints, $
  INPUT_RASTER1=Raster1, INPUT_RASTER2=Raster2)

Version History


ENVI 5.2, Service Pack 1

Introduced

API Version


3.2

See Also


ENVITask, ENVITask::Parameter, ENVISubsetRaster, ENVIGenerateTiePointsByCrossCorrelationTask, ENVIFilterTiePointsByGlobalTransformTask, ENVIFilterTiePointsByFundamentalMatrixTask, ENVIFilterTiePointsByPushbroomModelTask, ENVIImageToImageRegistrationTask, ENVITiePointSet



© 2018 Harris Geospatial Solutions, Inc. |  Legal
My Account    |    Store    |    Contact Us