>  Docs Center  >  ENVI API  >  Data Control  >  ENVIROI::ClearVectorRecords

ENVIROI::ClearVectorRecords

ENVIROI::ClearVectorRecords

The ClearVectorRecords method clears all the defined vector records for a given ENVIVector from an ROI.

Example


; Launch the application
e = ENVI()
 
; Use the IDLffShape object to read in the attributes
file = Filepath('qb_boulder_msi_vectors.shp', ROOT_DIR=e.Root_Dir, $
  SUBDIRECTORY=['data'])
shape = IDLffShape(file)
attributes = shape.GetAttributes(/ALL)
Obj_Destroy, shape
 
; Locate the records where the second attribute "CLASS_NAME"
; is equal to "water"
records = WHERE(attributes.(1) EQ 'water')
 
; Open the shapefile in ENVI
vector = e.OpenVector(file)
 
; Define a new ROI using these records
roi = EnviRoi(NAME='Water', COLOR="Dark Blue")
roi.AddVectorRecords, vector, records
 
; open and display the input file
file = Filepath('qb_boulder_pan', ROOT_DIR=e.Root_Dir, $
  SUBDIRECTORY=['data'])
   
raster = e.OpenRaster(file)
view = e.GetView()
layer = view.CreateLayer(raster)
view.Zoom, /FULL_EXTENT
 
; Display the shapefile
vectorLayer = view.CreateLayer(vector)
 
; Display the new "Water" ROI
roiLayer = layer.AddRoi(roi)
 
; Clear the geometry for this region
roi.ClearVectorRecords, vector

Syntax


ENVIROI.ClearVectorRecords, Vector [, ERROR=variable]

Arguments


Vector

The ENVIVector reference that contains the geometry records to remove.

Keywords


ERROR

Set this keyword to a named variable that will contain any error message issued during execution of this routine. If no error occurs, the ERROR variable will be set to a null string (''). If an error occurs and the routine is a function, then the function result will be undefined.When this keyword is not set and an error occurs, ENVI returns to the caller and execution halts. In this case, the error message is contained within !ERROR_STATE and can be caught using IDL's CATCH routine. See IDL Help for more information on !ERROR_STATE and CATCH.See Manage Errors for more information on error handling in ENVI programming.

Version History


ENVI 5.1

Introduced

API Version


3.3

See Also


ENVIROI, ENVIROI::AddVectorRecords, ENVIVector



© 2019 Harris Geospatial Solutions, Inc. |  Legal
My Account    |    Store    |    Contact Us