Welcome to the Harris Geospatial product documentation center. Here you will find reference guides, help documents, and product libraries.


Harris Geospatial / Docs Center / ENVI API / Application Control / ENVIProgressMessage

ENVIProgressMessage

ENVIProgressMessage

This function constructs an ENVIProgressMessage object to send to the ENVIBroadcastChannel. If the ENVI user interface is running, then a progress dialog will update.

Note: You must first issue ENVIStartMessage to display the progress dialog.

Example


PRO ProgressBarAbortExample
  COMPILE_OPT idl2
   
  ; Start the application
  e = ENVI()
   
  ; Get the broadcast channel to send messages to the ENVI system
  Channel = e.GetBroadcastChannel()
   
  ; Create an object that uniquely identifies the message.
  ; Use the ENVIAbortable object to check if progress
  ; was cancelled.
  Abort = ENVIAbortable()
   
  ; Broadcast a start message to the ENVI system
  Start = ENVIStartMessage('Progress Bar Title', Abort)
  Channel.Broadcast, Start
   
  ; Determine the number of steps to caculate
  ; percent complete for progress
  nSteps = 73
   
  ; Initialize progress
  Progress = ENVIProgressMessage('Executing Progress Message', $
    0, Abort)
   
  ; Iterate through the work
  FOR stepIndex=0, nSteps DO BEGIN
    
    ; Calculate progress for the step
    percentProgress = Round(stepIndex* 100.0/nSteps)
    
    ; Update progress percentage and broadcast the progress
    ; message to the ENVI system
    Progress.Percent = percentProgress
    Channel.Broadcast, Progress
   
    ; Check if aborted after sending progress to see if
    ; Abort_Requested was set by any listeners
    IF (Abort.Abort_Requested) THEN BREAK
   
    ; Simulate an analytic
    dataProcess = dist(1000)
   
    ; Print the step to see the abort working
    PRINT, stepIndex
  ENDFOR
   
  ; Broadcast a finish message to the ENVI system
  Finish = ENVIFinishMessage(Abort)
  Channel.Broadcast, Finish
END

Syntax


Result = ENVIProgressMessage(Message, Percent, SourceObject)

Return Value


This function returns a reference to an ENVIProgressMessage object.

Arguments


Message

Specify a string indicating the progress message in the progress dialog.

Percent

Specify an integer from 0 to 100, indicating the percent completed.

SourceObject

Specify an object to have the message uniquely identified. If you provide an object that implements the ENVIAbortable interface, then the progress dialog will have a Cancel button and you can query the ABORT_REQUESTED property on your object to determine if the user cancelled the progress dialog.

Keywords


ERROR (optional)

Set this keyword to a named variable that will contain any error message issued during execution of this routine. If no error occurs, the ERROR variable will be set to a null string (''). If an error occurs and the routine is a function, then the function result will be undefined.

When this keyword is not set and an error occurs, ENVI returns to the caller and execution halts. In this case, the error message is contained within !ERROR_STATE and can be caught using IDL's CATCH routine. See IDL Help for more information on !ERROR_STATE and CATCH.

See Manage Errors for more information on error handling in ENVI programming.

Version History


ENVI 5.3

Introduced

API Version


3.1.0

See Also


ENVIBroadcastChannel, ENVIStartMessage, ENVIFinishMessage, Messaging



© 2018 Harris Geospatial Solutions, Inc. |  Legal
My Account    |    Store    |    Contact Us