>  Docs Center  >  ENVI API  >  Data Control  >  ENVIGridDefinition::CreateGridFromCoordSys

ENVIGridDefinition::CreateGridFromCoordSys

ENVIGridDefinition::CreateGridFromCoordSys

This function method returns a new grid definition with the same spatial extent as the original but in a different coordinate system. It preserves the spatial extent, rows, and columns from the original grid. Use this method to reproject a raster to a new coordinate system.

Example


; Start the application
e = ENVI()
 
; Select input data
file = FILEPATH('qb_boulder_msi', ROOT_DIR=e.ROOT_DIR, $
  SUBDIRECTORY = ['data'])
raster = e.OpenRaster(file)
 
; Retrieve the grid parameters of the raster
PixelSize = raster.SPATIALREF.PIXEL_SIZE
CoordSysString = raster.SPATIALREF.COORD_SYS_STR
NumRows = raster.NROWS
NumCols = raster.NCOLUMNS
TiePointMap = raster.SPATIALREF.TIE_POINT_MAP
TiePointPixel = raster.SPATIALREF.TIE_POINT_PIXEL
CoordSys = ENVICoordSys(COORD_SYS_STR=CoordSysString)
 
; Create a grid definition for the original raster
GridDefGeo = ENVIGridDefinition(CoordSys, $
  PIXEL_SIZE=PixelSize, $
  NROWS=NumRows, $
  NCOLUMNS=NumCols, $
  TIE_POINT_MAP=TiePointMap, $
  TIE_POINT_PIXEL=TiePointPixel)
 
; Convert the grid to a UTM projection
UTMCoordSys = ENVICoordSys(COORD_SYS_CODE=32611)
GridDefUTM = GridDefGeo.CreateGridFromCoordSys(UTMCoordSys)
ReprojectedRaster = ENVISpatialGridRaster(raster, $
  GRID_DEFINITION=GridDefUTM)
 
; Display the reprojected raster
View = e.GetView()
Layer = View.CreateLayer(ReprojectedRaster)

Syntax


Result = ENVIGridDefinition.CreateGridFromCoordSys(CoordSys)

Arguments


CoordSys

Specify an ENVICoordSys object indicating the coordinate system that the raster will reproject to.

Keywords


Keywords are applied only during the initial creation of the object.

ERROR

Set this keyword to a named variable that will contain any error message issued during execution of this routine. If no error occurs, the ERROR variable will be set to a null string (''). If an error occurs and the routine is a function, then the function result will be undefined.

When this keyword is not set and an error occurs, ENVI returns to the caller and execution halts. In this case, the error message is contained within !ERROR_STATE and can be caught using IDL's CATCH routine. See IDL Help for more information on !ERROR_STATE and CATCH.

See Manage Errors for more information on error handling in ENVI programming.

Version History


ENVI 5.2

Introduced

API Version


3.3

See Also


ENVIGridDefinition, ENVICoordSys



© 2019 Harris Geospatial Solutions, Inc. |  Legal
My Account    |    Store    |    Contact Us