>  Docs Center  >  ENVI API  >  Processing  >  FilterTiePointsByGlobalTransformWithOrthorectification

FilterTiePointsByGlobalTransformWithOrthorectification

ENVIFilterTiePointsByGlobalTransformWithOrthorectificationTask

This task uses the global transform to filter the tie points. For orthorectified images, nadir, or near-nadir images, the transformation model between the first image and the second image fits an RST transform. When the scene is rather flat and the sensor is very far from the scene, the transformation model between the two images fits a first-order polynomial transform. Global transform is the most common filtering method.

The following diagram shows where this task belongs within an image-to-image registration workflow:

References

Jin, Xiaoying. ENVI automated image registration solutions. Harris Geospatial Systems whitepaper (2017). Available online at http://www.harrisgeospatial.com/Portals/0/pdfs/ENVI_Image_Registration_Whitepaper.pdf.

Jin, Xiaoying, and Robert Schafer. Method and system for automatic registration of images. Exelis, Inc., assignee; now owned by Harris Corporation. U.S. Patent No. 9,245,201 (issued January 26, 2016).

Example


This example uses sample Quickbird images and a USGS SRTM 1-arc second DEM. The files are available on the ENVI Resource DVD under the /image_reg directory or from the ENVI Tutorials web page. Click the "ENVI Tutorial Data" hyperlink. Copy the files to your local drive.

; Start the application
e = ENVI()
 
; Open QuickBird images and SRTM 1-arc second DEM
file1 = 'QuickBirdPhoenixWest.dat'
raster1 = e.OpenRaster(file1)
 
file2 = 'QuickBirdPhoenixEast.dat'
raster2 = e.OpenRaster(file2)
 
DEMFile = 'PhoenixDEMSubset.dat'
DEMRaster = e.OpenRaster(DEMFile)
 
; Get the task from the catalog of ENVITasks
Task = ENVITask('GenerateTiePointsByCrossCorrelationWithOrthorectification')
 
; Define inputs
Task.INPUT_RASTER1 = raster1
Task.INPUT_RASTER2 = raster2
Task.INPUT_DEM_RASTER = DEMRaster
Task.REQUESTED_NUMBER_OF_TIEPOINTS = 40
 
; Run the task
Task.Execute
 
; Get the output tie points
TiePoints = Task.OUTPUT_TIEPOINTS
OrthoTiePoints = Task.OUTPUT_ORTHORECTIFIED_TIEPOINTS
 
; Get the tie point filter task from the catalog of ENVITasks
FilterTask = ENVITask('FilterTiePointsByGlobalTransformWithOrthorectification')
 
; Define inputs for the filtering task
FilterTask.INPUT_TIEPOINTS = TiePoints
FilterTask.INPUT_ORTHORECTIFIED_TIEPOINTS = OrthoTiePoints
 
; Run the task
FilterTask.Execute
 
; Define outputs for the filtering task
FilteredTiePoints = FilterTask.OUTPUT_TIEPOINTS
 
; Get the image-to-image registration task
RegTask = ENVITask('ImageToImageRegistration')
 
; Define inputs
RegTask.INPUT_TIEPOINTS = FilteredTiePoints
RegTask.WARPING = 'Triangulation'
 
; Run the image-to-image registration task
RegTask.Execute
 
; Get the output raster
WarpedRaster = RegTask.OUTPUT_RASTER
 
; Get the collection of data objects currently available in the Data Manager
DataColl = e.Data
 
; Add the output to the Data Manager
DataColl.Add, WarpedRaster
 
; Display the result
View = e.GetView()
Layer = View.CreateLayer(WarpedRaster)

Syntax


Result = ENVITask('FilterTiePointsByGlobalTransformWithOrthorectification')

Input properties (Set, Get): ERROR_THRESHOLD, FITTING_TRANSFORM, INPUT_ORTHORECTIFIED_TIEPOINTS, INPUT_TIEPOINTS, OUTPUT_TIEPOINTS_URI

Output properties (Get only): OUTPUT_TIEPOINTS

Properties marked as "Set" are those that you can set to specific values. You can also retrieve their current values any time. Properties marked as "Get" are those whose values you can retrieve but not set.

Methods


This task inherits the following methods from ENVITask:

AddParameter

Execute

Parameter

ParameterNames

RemoveParameter

Properties


This task inherits the following properties from ENVITask:

COMMUTE_ON_DOWNSAMPLE

COMMUTE_ON_SUBSET

DESCRIPTION

DISPLAY_NAME

NAME

REVISION

TAGS

This task also contains the following properties:

ERROR_THRESHOLD (optional)

Specify the maximum error to allow for each tie point. The tie point with the largest error distance from the predicted location is iteratively removed until no tie points have an error greater than the this value. A first-order polynomial transform or RST transform is used to compute the predicted location from tie points on the first image to the points on the second image. The ERROR measurement represents the distance of each tie point in the second image to its predicted location, in pixel units. If at least one input image or warp image have RPC spatial reference and you specified a DEM file, ENVI performs an on-the-fly orthorectification on the input image(s) for geometric filtering by global transform, resulting in a more accurate image registration.

The default value is 5.0. A higher value keeps more tie points with larger fitting errors. If you prefer to keep most tie points, enter a high value such as 100.

FITTING_TRANSFORM (optional)

Specify the transform to use when automatically filtering tie points. The default is First-Order Polynomial.

  • First-Order Polynomial: A first-order polynomial warp includes an XY interaction term to account for image shear.
  • RST: Rotation, scaling, and translation; this is the simplest method. It does not allow for shearing in the image warp.

INPUT_ORTHORECTIFIED_TIEPOINTS (required)

This is a reference to the orthorectified tie points generated by ENVIGenerateTiePointsByCrossCorrelationWithOrthorectificationTask or ENVIGenerateTiePointsByMutualInformationWithOrthorectificationTask.

INPUT_TIEPOINTS (required)

This is a reference to an ENVITiePointSet object.

OUTPUT_TIEPOINTS

This is a reference to an ENVITiePointSet object with the output tie points.

OUTPUT_TIEPOINTS_URI (optional)

Specify a string with the fully qualified path and filename for OUTPUT_TIEPOINTS.

Version History


ENVI 5.2, Service Pack 1

Introduced

API Version


3.3

See Also


ENVITask, ENVITask::Parameter, ENVISubsetRaster, ENVIGenerateTiePointsByMutualInformationWithOrthorectificationTask, ENVIGenerateTiePointsByCrossCorrelationTaskWithOrthorectificationTask, ENVIImageToImageRegistrationTask, ENVITiePointSet



© 2019 Harris Geospatial Solutions, Inc. |  Legal
My Account    |    Store    |    Contact Us